http://i.imgur.com/Fwis9wl.jpg
to jest w ustawienia > system > powiadomienia i akcje, tak?
Musisz zrestartować cache tych powiadomień :)

1. Tworzysz plik .bat z zawartością
   
   Kod:

   :: Created by: Shawn Brink
   :: http://www.tenforums.com
   :: Tutorial: http://www.tenforums.com/tutorials/5662-notification-area-icons-reset-windows-10-a.html
   @echo off
   set regPath=HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\CurrentVersion\TrayNotify
   set regKey1=IconStreams
   set regKey2=PastIconsStream
   echo.
   echo The Explorer process must be temporarily killed before deleting your notification area icons cache.
   echo.
   echo Please SAVE ALL OPEN WORK before continuing.
   echo.
   pause
   echo.
   taskkill /IM explorer.exe /F
   echo.
   FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey1% ^| find /i "%regkey1%"') do goto IconStreams
   echo Registry key "IconStreams" already deleted.
   echo.
   :verify-PastIconsStream
   FOR /F "tokens=*" %%a in ('Reg Query "%regpath%" /v %regkey2% ^| find /i "%regkey2%"') do goto PastIconsStream
   echo Registry key "PastIconsStream" already deleted.
   echo.
   goto restart
   :IconStreams
   reg delete "%regpath%" /f /v "%regkey1%"
   goto verify-PastIconsStream
   :PastIconsStream
   reg delete "%regpath%" /f /v "%regkey2%"
   :restart
   echo.
   echo.
   echo You will need to restart the PC to finish resetting your notification area icons.
   echo.
   CHOICE /C:YN /M "Do you want to restart the PC now?"
   IF ERRORLEVEL 2 goto no
   IF ERRORLEVEL 1 goto yes
   :no
   echo.
   echo.
   echo Restarting explorer....
   echo.
   echo Please remember to restart the PC later to finish resetting your notification area icons.
   echo.
   start explorer.exe
   pause
   exit /B
   :yes
   shutdown /r /f /t 00

2. Uruchomienie wyłączy explorera i zrestartuje PC
3. Postępuj wg istrukcji
   
   
   
4. Tyle

 
[hr]
 

HKEY_CLASSES_ROOT\*\shellex\ContextMenuHandlers
Zobacz czy możesz zedytować nazwę tutaj, wyszukując odpowiedni folder.

 

Nie chce mi się szukać dokładnie więc spróbujemy sposobu z ogólną przebudową cache ikonek plikiem .bat

Kod:

:: Created by: Shawn Brink
:: http://www.tenforums.com
:: Tutorial: http://www.tenforums.com/tutorials/5645-icon-cache-rebuild-windows-10-a.html
@echo off
set iconcache=%localappdata%\IconCache.db
echo.
echo The explorer process must be temporarily killed before deleting the IconCache.db file.
echo.
echo Please SAVE ALL OPEN WORK before continuing.
echo.
pause
echo.
If exist "%iconcache%" goto delete
echo.
echo The IconCache.db file has already been deleted.
goto restart
:delete
echo.
echo Attempting to delete IconCache.db file...
echo.
ie4uinit.exe -ClearIconCache
taskkill /IM explorer.exe /F
del "%iconcache%" /A
start explorer.exe
echo.
echo IconCache.db file has been successfully deleted.
goto restart
:restart
echo.
echo.
echo You will need to restart the PC to finish rebuilding your icon cache.
echo.
CHOICE /C:YN /M "Do you want to restart the PC now?"
IF ERRORLEVEL 2 goto no
IF ERRORLEVEL 1 goto yes
:yes
shutdown /r /f /t 00
:no
exit /B

A do menu kontekstowego, może coś tutaj pomoże :v
http://www.online-tech-tips.com/computer-tips/windows-right-click-context-menu/